emacs: Handle autoloading Emacs packages installed with Guix.

* emacs/guix-emacs.el: New file.
* emacs.am (ELFILES): Add it.
* emacs/guix-backend.el (guix-after-repl-operation-hook): Add
  'guix-emacs-load-autoloads-maybe'.
* emacs/guix-init.el.in: Autoload emacs packages.
  (guix-package-enable-at-startup): New variable.

3 files changed, 96 insertions, 1 deletions

diff --git a/emacs/guix-backend.el b/emacs/guix-backend.el
index a320eae35a..73a429b9ee 100644
--- a/emacs/guix-backend.el
+++ b/emacs/guix-backend.el
@@ -52,6 +52,7 @@
 ;;; Code:
 
 (require 'geiser-mode)
+(require 'guix-emacs)
 
 (defvar guix-load-path
   (file-name-directory (or load-file-name
@@ -125,7 +126,8 @@ This REPL is used for receiving information only if
   "Hook run before executing an operation in Guix REPL.")
 
 (defvar guix-after-repl-operation-hook
-  '(guix-repl-operation-success-message)
+  '(guix-emacs-load-autoloads-maybe
+    guix-repl-operation-success-message)
   "Hook run after executing successful operation in Guix REPL.")
 
 (defvar guix-repl-operation-p nil
diff --git a/emacs/guix-emacs.el b/emacs/guix-emacs.el
new file mode 100644
index 0000000000..512a2e2b1a
--- /dev/null
+++ b/emacs/guix-emacs.el
@@ -0,0 +1,79 @@
+;;; guix-emacs.el --- Emacs packages installed with Guix
+
+;; Copyright © 2014 Alex Kost <alezost@gmail.com>
+
+;; This file is part of GNU Guix.
+
+;; GNU Guix is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Guix is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; This file provides auxiliary code for working with Emacs packages
+;; installed with Guix.
+
+;;; Code:
+
+(require 'guix-profiles)
+
+(defcustom guix-emacs-activate-after-operation t
+  "Activate Emacs packages after installing.
+If nil, do not load autoloads of the Emacs packages after
+they are successfully installed."
+  :type 'boolean
+  :group 'guix)
+
+(defvar guix-emacs-autoloads nil
+  "List of the last loaded Emacs autoloads.")
+
+(defun guix-emacs-directory (&optional profile)
+  "Return directory with Emacs packages installed in PROFILE.
+If PROFILE is nil, use `guix-user-profile'."
+  (expand-file-name "share/emacs/site-lisp"
+                    (or profile guix-user-profile)))
+
+(defun guix-emacs-find-autoloads (&optional profile)
+  "Return list of autoloads of Emacs packages installed in PROFILE.
+If PROFILE is nil, use `guix-user-profile'.
+Return nil if there are no emacs packages installed in PROFILE."
+  (let ((dir (guix-emacs-directory profile)))
+    (if (file-directory-p dir)
+        (directory-files dir 'full-name "-autoloads\\.el\\'")
+      (message "Directory '%s' does not exist." dir)
+      nil)))
+
+;;;###autoload
+(defun guix-emacs-load-autoloads (&optional all)
+  "Load autoloads for Emacs packages installed in a user profile.
+If ALL is nil, activate only those packages that were installed
+after the last activation, otherwise activate all Emacs packages
+installed in `guix-user-profile'."
+  (interactive "P")
+  (let* ((autoloads (guix-emacs-find-autoloads))
+         (files (if all
+                    autoloads
+                  (cl-nset-difference autoloads guix-emacs-autoloads
+                                      :test #'string=))))
+    (dolist (file files)
+      (load file 'noerror))
+    (setq guix-emacs-autoloads autoloads)))
+
+(defun guix-emacs-load-autoloads-maybe ()
+  "Load autoloads for Emacs packages if needed.
+See `guix-emacs-activate-after-operation' for details."
+  (and guix-emacs-activate-after-operation
+       (guix-emacs-load-autoloads)))
+
+(provide 'guix-emacs)
+
+;;; guix-emacs.el ends here
diff --git a/emacs/guix-init.el.in b/emacs/guix-init.el.in
index 775c90fef9..4e40d7171a 100644
--- a/emacs/guix-init.el.in
+++ b/emacs/guix-init.el.in
@@ -1,7 +1,21 @@
 (require 'guix-autoloads)
+(require 'guix-emacs)
 
 (defvar guix-load-path
   (replace-regexp-in-string "${prefix}" "@prefix@" "@emacsuidir@")
   "Directory with scheme files for \"guix.el\" package.")
 
+(defcustom guix-package-enable-at-startup t
+  "If non-nil, activate Emacs packages installed in a user profile.
+Set this variable to nil before requiring `guix-init' file to
+avoid loading autoloads of Emacs packages installed in
+`guix-user-profile'."
+  :type 'boolean
+  :group 'guix)
+
+(add-to-list 'load-path (guix-emacs-directory))
+
+(when guix-package-enable-at-startup
+  (guix-emacs-load-autoloads 'all))
+
 (provide 'guix-init)