* Added tex plugin to generate images from latex code.

  Contributed by Patrick Winnertz as a GSoC project.

4 files changed, 215 insertions, 2 deletions

diff --git a/IkiWiki/Plugin/tex.pm b/IkiWiki/Plugin/tex.pm
new file mode 100644
index 000000000..7a95697b9
--- /dev/null
+++ b/IkiWiki/Plugin/tex.pm
@@ -0,0 +1,181 @@
+#!/usr/bin/perl
+# Licensed under GPL v2 or greater
+# (c) 2007 Patrick Winnertz <patrick.winnertz@skolelinux.org>
+
+package IkiWiki::Plugin::tex;
+use warnings;
+use strict;
+use Digest::MD5 qw(md5_hex);
+use File::Temp qw(tempdir);
+use URI::Escape qw(uri_escape);
+use IkiWiki 2.00;
+
+sub import { #{{{
+	hook(type => "preprocess", id => "tex", call => \&preprocess);
+} #}}}
+
+sub preprocess (@) { #{{{
+	my %params = @_;
+	
+	my $height = $params{height};
+	if (! defined $height || ! length $height) {
+		$height = 12;
+	}
+	else {
+		$height =~ s#(\d+)#$1#;
+	}
+	
+	my $code = $params{code};
+	if (! defined $code && ! length $code) {
+		return "[[tex ".gettext("missing tex code"). "]]";
+	}
+
+	if (check($code)) {
+		return create($code, check_height($height), \%params);
+	}
+	else {
+		return "[[tex ".gettext("code includes disallowed latex commands"). "]]";
+	}
+} #}}}
+
+sub check_height ($) { #{{{
+	# Since latex doesn't support unlimited scaling this function
+	# returns the closest supported size.
+	my $height =shift;
+
+	my @allowed=(8,9,10,11,12,14,17,20);
+
+	my $ret;
+	my $fit;
+	foreach my $val (@allowed) {
+		my $f = abs($val - $height);
+		if (! defined($fit) || $f < $fit ) {
+			$ret=$val;
+			$fit=$f;
+		}
+	}
+	return $ret;
+} #}}}
+
+sub create ($$$) { #{{{
+	# This function calls the image generating function and returns
+	# the <img .. /> for the generated image.
+	my $code = shift;
+	my $height = shift;
+	my $params = shift;
+
+	if (! defined($height) and not length($height) ) {
+		$height = 12;
+	}
+
+	my $digest = md5_hex($code, $height);
+
+	my $teximgdir = "/teximages";
+	my $imglink = "$teximgdir/$digest.png";
+	my $imglog = "$teximgdir/$digest.log";
+	will_render($params->{destpage}, $imglink);
+	will_render($params->{destpage}, $imglog);
+
+	my $imgurl;
+	my $logurl;
+	if (! $params->{preview}) {
+		$imgurl = urlto($imglink, $params->{destpage});
+		$logurl = urlto($imglog, $params->{destpage});
+	}
+	else {
+		$imgurl="$config{url}/$teximgdir/$digest.png";
+		$logurl="$config{url}/$teximgdir/$digest.log";
+	}
+	
+	if (-e "$config{destdir}/$imglink" ||
+	    gen_image($code, $height, $digest, $teximgdir)) {
+		return qq{<img src="$imgurl" alt="}.uri_escape($code).qq{" class="teximage" />};
+	}
+	else {
+		return qq{[[tex <a href="$logurl">}.gettext("failed to generate image from code")."</a>]]";
+	}
+} #}}}
+
+sub gen_image ($$$$) { #{{{
+	# Actually creates the image.
+	my $code = shift;
+	my $height = shift;
+	my $digest = shift;
+	my $imagedir = shift;
+
+	#TODO This should move into the setup file.
+	my $tex = '\documentclass['.$height.'pt]{scrartcl}';
+	$tex .= '\usepackage[version=3]{mhchem}';
+	$tex .= '\usepackage{amsmath}';
+	$tex .= '\usepackage{amsfonts}';
+	$tex .= '\usepackage{amssymb}';
+	$tex .= '\pagestyle{empty}';
+	$tex .= '\begin{document}';
+	$tex .= '$$'.$code.'$$';
+	$tex .= '\end{document}';
+
+	my $tmp = eval { create_tmp_dir($digest) };
+	if (! $@ &&
+	    writefile("$digest.tex", $tmp, $tex) &&
+	    system("cd $tmp; latex --interaction=nonstopmode $tmp/$digest.tex > /dev/null") == 0 &&
+	    system("dvips -E $tmp/$digest.dvi -o $tmp/$digest.ps 2> $tmp/$digest.log") == 0 &&
+	    # ensure destination directory exists
+	    writefile("$imagedir/$digest.png", $config{destdir}, "") &&
+	    system("convert -density 120  -trim -transparent \"#FFFFFF\" $tmp/$digest.ps $config{destdir}/$imagedir/$digest.png > $tmp/$digest.log") == 0) {
+		return 1;
+	}
+	else {
+		# store failure log
+		my $log;
+		{
+			open(my $f, '<', "$tmp/$digest.log");
+			local $/=undef;
+			$log = <$f>;
+			close($f);
+		}
+		writefile("$digest.log", "$config{destdir}/$imagedir", $log);
+
+		return 0;
+	}
+} #}}}
+
+sub create_tmp_dir ($) { #{{{
+	# Create a temp directory, it will be removed when ikiwiki exits.
+	my $base = shift;
+
+	my $template = $base.".XXXXXXXXXX";
+	my $tmpdir = tempdir($template, TMPDIR => 1, CLEANUP => 1);
+	return $tmpdir;
+} #}}}
+
+sub check ($) { #{{{
+	# Check if the code is ok
+	my $code = shift;
+
+	my @badthings = (
+		qr/\$\$/,
+		qr/\\include/,
+		qr/\\includegraphic/,
+		qr/\\usepackage/,
+		qr/\\newcommand/, 
+		qr/\\renewcommand/,
+		qr/\\def/,
+		qr/\\input/,
+		qr/\\open/,
+		qr/\\loop/,
+		qr/\\errorstopmode/,
+		qr/\\scrollmode/,
+		qr/\\batchmode/,
+		qr/\\read/,
+		qr/\\write/,
+	);
+	
+	foreach my $thing (@badthings) {
+		if ($code =~ m/$thing/ ) {
+			return 0;
+		}
+	}
+	return 1;
+} #}}}
+
+1
diff --git a/debian/changelog b/debian/changelog
index 11f1c40c8..70b7d040e 100644
--- a/debian/changelog
+++ b/debian/changelog
@@ -46,8 +46,10 @@ ikiwiki (2.6) UNRELEASED; urgency=low
   * Add proper Homepage field to Debian package (needs uber-new dpkg).
   * Add monotone support, contributed by William Uther.
   * Avoid ugly gettext messages if LANG is empty. Closes: #439035
+  * Added tex plugin to generate images from latex code.
+    Contributed by Patrick Winnertz as a GSoC project.
 
- -- Joey Hess <joeyh@debian.org>  Tue, 21 Aug 2007 17:18:50 -0400
+ -- Joey Hess <joeyh@debian.org>  Tue, 21 Aug 2007 20:34:59 -0400
 
 ikiwiki (2.5) unstable; urgency=low
 
diff --git a/doc/plugins/tex.mdwn b/doc/plugins/tex.mdwn
new file mode 100644
index 000000000..aebac26ed
--- /dev/null
+++ b/doc/plugins/tex.mdwn
@@ -0,0 +1,8 @@
+[[template id=plugin name=tex author="[[PatrickWinnertz]]"]]
+[[tag type/chrome type/slow]]
+
+This plugin renders LaTeX code into an image and inserts it into the page.
+
+# examples
+
+	\[[tex code="\ce{[Cu(NH3)3]^{2+}}"]]
diff --git a/doc/todo/latex.mdwn b/doc/todo/latex.mdwn
index 981c07564..f23f0a254 100644
--- a/doc/todo/latex.mdwn
+++ b/doc/todo/latex.mdwn
@@ -162,7 +162,29 @@ Mh... not really fixed :S I added it into the return but it is somehow ignored.
 
 Okay, the last version of the tex plugin for ikiwiki can be downloaded [here](https://www.der-winnie.de/~winnie/gsoc07/tex.pm). 
 
+> I've looked this over, fixed the indenting, fixed some variable names
+> ("$foo" is a bad variable name), removed a gratuotuous use of `tie`,
+> fixed a bug (the first time it was run, it tried to write the png file
+> before the teximages/ directory existed) and checked the result in.
+> 
+> Can you please flesh out [[plugins/tex]] with
+> whatever documentation people who know tex will expect to see?
+>
+> Also, please review my changes. In particular, I changed the @badthings
+> array to use qr//, which is much clearer, but it needs to be tested that
+> I didn't break the checking code when I did it. It would be nice to write
+> a test case that tries to feed it bad code and makes sure it rejects it.
+>
+> Question: does it really make sense to have an alt tag for the image
+> that contains the tex code? Will that make any sense when browsing
+> without images?
+>
+> Note: I removed the style= attribute, since as I've told you, the
+> htmlsanitizer strips those since they can be used to insert javascript. I
+> put in a class=teximage instead; the style sheet could be modified to
+> style that, if you want to send a patch for that.
+> 
+> --[[Joey]]
 
 [[tag soc]]
-
 [[tag wishlist]]