(define-module (guix-qa-frontpage view home)
  #:use-module (srfi srfi-1)
  #:use-module (ice-9 match)
  #:use-module (guix-qa-frontpage view util)
  #:export (home))

(define (home branches)
  (layout
   #:description "Guix Quality Assurance"
   #:body
   `((main
      (p
       (@ (style "width: unset; text-align: center; padding: 2rem; border: 0.3rem dashed red;"))
       "This service is in the very early stages of development. "
       (br)
       "Find the code in "
       (a (@ (href "https://git.savannah.gnu.org/cgit/guix/qa-frontpage.git/"))
          "this git repository")
       " and send patches to "
       (a (@ (href "mailto:guix-devel@gnu.org"))
          "guix-devel@gnu.org")
       ".")
      (div
       (@ (class "row"))
       (section
        (a (@ (href "/branch/master"))
           (h2 "branch: master"))))

      (h2 "Branches")
      (div
       (@ (class "row"))
       (table
        (thead
         (tr (th "Branch")
             (th "Request to merge")))
        (tbody
         ,@(append-map
            (match-lambda
              ((branch . details)
               (let ((issue-number
                      (assoc-ref details "issue_number")))
                 `((tr
                    (td (a (@ (href ,(string-append "/branch/" branch))
                              (style "font-family: monospace;"))
                           ,branch))
                    (td ,@(if issue-number
                              `((a (@ (href ,(string-append
                                              "https://issues.guix.gnu.org/"
                                              (number->string issue-number))))
                                   "#" ,issue-number))
                              '())))))))
            branches))))

      (h2 ,(gettext "Patches" "guix-qa-frontpage"))
      (a (@ (href "/patches"))
         "List of issues for patches")
      ;; (div
      ;;  (@ (class "row two-element-row"))
      ;;  (section
      ;;   (h3 "Checks passing"))
      ;;  (section
      ;;   (h3 "Unreviewed")))
      ))))