1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
|
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017 Peter Mikkelsen <petermikkelsen10@gmail.com>
;;; Copyright © 2019 Ricardo Wurmus <rekado@elephly.net>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu services audio)
#:use-module (guix gexp)
#:use-module (gnu services)
#:use-module (gnu services shepherd)
#:use-module (gnu packages mpd)
#:use-module (guix records)
#:use-module (ice-9 match)
#:export (mpd-output
mpd-output?
mpd-credential
mpd-credential?
mpd-configuration
mpd-configuration?
mpd-service-type))
;;; Commentary:
;;;
;;; Audio related services
;;;
;;; Code:
(define-record-type* <mpd-credential>
mpd-credential make-mpd-credential
mpd-credential?
(password mpd-credential-password
;; valid: any string that does not contain #\@
(default ""))
(permissions mpd-credential-permissions
;; valid: any subset of read, add, control and admin
(default '())))
(define-record-type* <mpd-output>
mpd-output make-mpd-output
mpd-output?
(type mpd-output-type
(default "pulse"))
(name mpd-output-name
(default "MPD"))
(enabled? mpd-output-enabled?
(default #t))
(tags? mpd-output-tags?
(default #t))
(always-on? mpd-output-always-on?
(default #f))
(mixer-type mpd-output-mixer-type
;; valid: hardware, software, null, none
(default #f))
(extra-options mpd-output-extra-options
(default '())))
(define-record-type* <mpd-configuration>
mpd-configuration make-mpd-configuration
mpd-configuration?
(user mpd-configuration-user
(default "mpd"))
(music-dir mpd-configuration-music-dir
(default "~/Music"))
(playlist-dir mpd-configuration-playlist-dir
(default "~/.mpd/playlists"))
(db-file mpd-configuration-db-file
(default "~/.mpd/tag_cache"))
(state-file mpd-configuration-state-file
(default "~/.mpd/state"))
(sticker-file mpd-configuration-sticker-file
(default "~/.mpd/sticker.sql"))
(port mpd-configuration-port
(default "6600"))
(address mpd-configuration-address
(default "any"))
(credentials mpd-configuration-credentials
(default '()))
(default-permissions mpd-configuration-default-permissions
(default '(read add control admin)))
(outputs mpd-configuration-outputs
(default (list (mpd-output)))))
(define (mpd-permissions->string permissions)
(string-join (map symbol->string
permissions)
","))
(define (mpd-credential->string credential)
"Convert the USER of type <mpd-credential> to a configuration file snippet."
(format #f
"password \"~a@~a\"\n"
(mpd-credential-password credential)
(mpd-permissions->string
(mpd-credential-permissions credential))))
(define (mpd-output->string output)
"Convert the OUTPUT of type <mpd-output> to a configuration file snippet."
(let ((extra (string-join
(map (match-lambda
((key . value)
(format #f " ~a \"~a\""
(string-map
(lambda (c) (if (char=? c #\-) #\_ c))
(symbol->string key))
value)))
(mpd-output-extra-options output))
"\n")))
(format #f "\
audio_output {
type \"~a\"
name \"~a\"
~:[ enabled \"no\"~%~;~]\
~:[ tags \"no\"~%~;~]\
~:[~; always_on \"yes\"~%~]\
~@[ mixer_type \"~a\"~%~]\
~a~%}~%"
(mpd-output-type output)
(mpd-output-name output)
(mpd-output-enabled? output)
(mpd-output-tags? output)
(mpd-output-always-on? output)
(mpd-output-mixer-type output)
extra)))
(define (mpd-config->file config)
(apply
mixed-text-file "mpd.conf"
"pid_file \"" (mpd-file-name config "pid") "\"\n"
"default_permissions \""
(mpd-permissions->string
(mpd-configuration-default-permissions config))
"\"\n"
(append (map mpd-output->string
(mpd-configuration-outputs config))
(map mpd-credential->string
(mpd-configuration-credentials config))
(map (match-lambda
((config-name config-val)
(string-append config-name " \"" (config-val config) "\"\n")))
`(("user" ,mpd-configuration-user)
("music_directory" ,mpd-configuration-music-dir)
("playlist_directory" ,mpd-configuration-playlist-dir)
("db_file" ,mpd-configuration-db-file)
("state_file" ,mpd-configuration-state-file)
("sticker_file" ,mpd-configuration-sticker-file)
("port" ,mpd-configuration-port)
("bind_to_address" ,mpd-configuration-address))))))
(define (mpd-file-name config file)
"Return a path in /var/run/mpd/ that is writable
by @code{user} from @code{config}."
(string-append "/var/run/mpd/"
(mpd-configuration-user config)
"/" file))
(define (mpd-shepherd-service config)
(shepherd-service
(documentation "Run the MPD (Music Player Daemon)")
(provision '(mpd))
(start #~(make-forkexec-constructor
(list #$(file-append mpd "/bin/mpd")
"--no-daemon"
#$(mpd-config->file config))
#:pid-file #$(mpd-file-name config "pid")
#:environment-variables
;; Required to detect PulseAudio when run under a user account.
'(#$(string-append
"XDG_RUNTIME_DIR=/run/user/"
(number->string
(passwd:uid
(getpwnam (mpd-configuration-user config))))))
#:log-file #$(mpd-file-name config "log")))
(stop #~(make-kill-destructor))))
(define (mpd-service-activation config)
(with-imported-modules '((guix build utils))
#~(begin
(use-modules (guix build utils))
(define %user
(getpw #$(mpd-configuration-user config)))
(let ((directory #$(mpd-file-name config "")))
(mkdir-p directory)
(chown directory (passwd:uid %user) (passwd:gid %user))))))
(define mpd-service-type
(service-type
(name 'mpd)
(description "Run the Music Player Daemon (MPD).")
(extensions
(list (service-extension shepherd-root-service-type
(compose list mpd-shepherd-service))
(service-extension activation-service-type
mpd-service-activation)))
(default-value (mpd-configuration))))
|