Add (distro) with a package searching facility.

* Makefile.am (MODULES): Add `distro.scm'.

* distro.scm: New file.
* po/POTFILES.in: Add it.

* tests/packages.scm ("find-packages-by-name", "find-packages-by-name
  with version"): New tests.

4 files changed, 110 insertions, 1 deletions

diff --git a/Makefile.am b/Makefile.am
index af68ec82b7..363839435a 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -28,6 +28,7 @@ MODULES =					\
   guix/build/utils.scm				\
   guix/packages.scm				\
   guix.scm					\
+  distro.scm					\
   distro/base.scm
 
 GOBJECTS = $(MODULES:%.scm=%.go)
diff --git a/distro.scm b/distro.scm
new file mode 100644
index 0000000000..784e537deb
--- /dev/null
+++ b/distro.scm
@@ -0,0 +1,94 @@
+;;; Guix --- Nix package management from Guile.         -*- coding: utf-8 -*-
+;;; Copyright (C) 2012 Ludovic Courtès <ludo@gnu.org>
+;;;
+;;; This file is part of Guix.
+;;;
+;;; Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (distro)
+  #:use-module (guix packages)
+  #:use-module (ice-9 ftw)
+  #:use-module (srfi srfi-1)
+  #:use-module (srfi srfi-26)
+  #:export (find-packages-by-name))
+
+;;; Commentary:
+;;;
+;;; General utilities for the software distribution---i.e., the modules under
+;;; (distro ...).
+;;;
+;;; Code:
+
+(define _ (cut gettext <> "guix"))
+
+(define %distro-module-directory
+  ;; Absolute path of the (distro ...) module root.
+  (string-append (dirname (search-path %load-path "distro.scm"))
+                 "/distro"))
+
+(define (package-files)
+  "Return the list of files that implement distro modules."
+  (define prefix-len
+    (string-length (dirname %distro-module-directory)))
+
+  (file-system-fold (const #t)                    ; enter?
+                    (lambda (path stat result)    ; leaf
+                      (if (string-suffix? ".scm" path)
+                          (cons (substring path prefix-len) result)
+                          result))
+                    (lambda (path stat result)    ; down
+                      result)
+                    (lambda (path stat result)    ; up
+                      result)
+                    (const #f)                    ; skip
+                    (lambda (path stat errno result)
+                      (format (current-error-port)
+                              (_ "warning: cannot access `~a': ~a")
+                              path (strerror errno))
+                      result)
+                    '()
+                    %distro-module-directory
+                    stat))
+
+(define (package-modules)
+  "Return the list of modules that provide packages for the distribution."
+  (define not-slash
+    (char-set-complement (char-set #\/)))
+
+  (filter-map (lambda (path)
+                (let ((name (map string->symbol
+                                 (string-tokenize (string-drop-right path 4)
+                                                  not-slash))))
+                  (false-if-exception (resolve-interface name))))
+              (package-files)))
+
+(define* (find-packages-by-name name #:optional version)
+  "Return the list of packages with the given NAME.  If VERSION is not #f,
+then only return packages whose version is equal to VERSION."
+  (define right-package?
+    (if version
+        (lambda (p)
+          (and (package? p)
+               (string=? (package-name p) name)
+               (string=? (package-version p) version)))
+        (lambda (p)
+          (and (package? p)
+               (string=? (package-name p) name)))))
+
+  (append-map (lambda (module)
+                (filter right-package?
+                        (module-map (lambda (sym var)
+                                      (variable-ref var))
+                                    module)))
+              (package-modules)))
diff --git a/po/POTFILES.in b/po/POTFILES.in
index 39ff38db32..1f231a7c1f 100644
--- a/po/POTFILES.in
+++ b/po/POTFILES.in
@@ -1,2 +1,3 @@
 # List of source files which contain translatable strings.
+distro.scm
 distro/base.scm
diff --git a/tests/packages.scm b/tests/packages.scm
index 8df58a8bd2..eef7d32a35 100644
--- a/tests/packages.scm
+++ b/tests/packages.scm
@@ -22,8 +22,11 @@
   #:use-module (guix utils)
   #:use-module (guix derivations)
   #:use-module (guix packages)
+  #:use-module (distro)
   #:use-module (distro base)
-  #:use-module (srfi srfi-64))
+  #:use-module (srfi srfi-26)
+  #:use-module (srfi srfi-64)
+  #:use-module (ice-9 match))
 
 ;; Test the high-level packaging layer.
 
@@ -43,6 +46,16 @@
          (and (build-derivations %store (list drv))
               (file-exists? (string-append out "/bin/hello"))))))
 
+(test-assert "find-packages-by-name"
+  (match (find-packages-by-name "hello")
+    (((? (cut eq? hello <>))) #t)
+    (wrong (pk 'find-packages-by-name wrong #f))))
+
+(test-assert "find-packages-by-name with version"
+  (match (find-packages-by-name "hello" (package-version hello))
+    (((? (cut eq? hello <>))) #t)
+    (wrong (pk 'find-packages-by-name wrong #f))))
+
 (test-end "packages")