AC_INIT([guix-build-coordinator], [m4_translit(m4_esyscmd([cat VERSION]),m4_newline)])
AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([gnu color-tests -Wall -Wno-portability foreign])

GUILE_PKG([3.0])
GUILE_PROGS
if test "x$GUILD" = "x"; then
   AC_MSG_ERROR(['guild' binary not found; please check your guile-3.x installation.])
fi

if test "$cross_compiling" != no; then
   GUILE_TARGET="--target=$host_alias"
   AC_SUBST([GUILE_TARGET])
fi

AC_PATH_PROG([guix], [guix])

AC_PATH_PROG([sqitch], [sqitch])
AC_PATH_PROG([sqlite3], [sqlite3])
AC_PATH_PROG([psql], [psql])
AC_PATH_PROG([bzip2], [bzip2])

dnl Check for Guile-zlib.
GUILE_MODULE_AVAILABLE([have_guile_zlib], [(zlib)])
if test "x$have_guile_zlib" != "xyes"; then
  AC_MSG_ERROR([Guile-zlib is missing; please install it.])
fi

dnl Check for Guile-lzlib.
GUILE_MODULE_AVAILABLE([have_guile_lzlib], [(lzlib)])
if test "x$have_guile_lzlib" != "xyes"; then
  AC_MSG_ERROR([Guile-lzlib is missing; please install it.])
fi

dnl Check for Guile-lib.
GUILE_MODULE_AVAILABLE([have_guile_lib], [(logging logger)])
if test "x$have_guile_lib" != "xyes"; then
  AC_MSG_ERROR([Guile-lib is missing; please install it.])
fi

AC_CONFIG_FILES([Makefile])
AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
AC_CONFIG_FILES([guix-build-coordinator/config.scm])
AC_CONFIG_FILES(
  [scripts/guix-build-coordinator],
  [chmod +x scripts/guix-build-coordinator]
)
AC_CONFIG_FILES(
  [scripts/guix-build-coordinator-agent],
  [chmod +x scripts/guix-build-coordinator-agent]
)
AC_CONFIG_FILES(
  [scripts/guix-build-coordinator-queue-builds-from-guix-data-service],
  [chmod +x scripts/guix-build-coordinator-queue-builds-from-guix-data-service]
)

AC_OUTPUT