1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
|
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2014 Mark H Weaver <mhw@netris.org>
;;; Copyright © 2014 Alex Kost <alezost@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build emacs-utils)
#:export (%emacs
emacs-batch-eval
emacs-batch-edit-file
emacs-generate-autoloads
emacs-byte-compile-directory
emacs-substitute-sexps
emacs-substitute-variables))
;;; Commentary:
;;;
;;; Tools to programmatically edit files using Emacs,
;;; e.g. to replace entire s-expressions in elisp files.
;;;
;;; Code:
(define %emacs
;; The `emacs' command.
(make-parameter "emacs"))
(define (emacs-batch-eval expr)
"Run Emacs in batch mode, and execute the elisp code EXPR."
(unless (zero? (system* (%emacs) "--quick" "--batch"
(format #f "--eval=~S" expr)))
(error "emacs-batch-eval failed!" expr)))
(define (emacs-batch-edit-file file expr)
"Load FILE in Emacs using batch mode, and execute the elisp code EXPR."
(unless (zero? (system* (%emacs) "--quick" "--batch"
(string-append "--visit=" file)
(format #f "--eval=~S" expr)))
(error "emacs-batch-edit-file failed!" file expr)))
(define (emacs-generate-autoloads name directory)
"Generate autoloads for Emacs package NAME placed in DIRECTORY."
(let* ((file (string-append directory "/" name "-autoloads.el"))
(expr `(let ((backup-inhibited t)
(generated-autoload-file ,file))
(update-directory-autoloads ,directory))))
(emacs-batch-eval expr)))
(define* (emacs-byte-compile-directory dir #:optional (dependency-dirs '()))
"Byte compile all files in DIR and its sub-directories. Before compiling
the files, add DIR and all directories in DEPENDENCY-DIRS to 'load-path'."
(let ((expr `(progn
(add-to-list 'load-path ,dir)
(when ',dependency-dirs
(setq load-path (append ',dependency-dirs load-path)))
(byte-recompile-directory (file-name-as-directory ,dir) 0))))
(emacs-batch-eval expr)))
(define-syntax emacs-substitute-sexps
(syntax-rules ()
"Substitute the S-expression immediately following the first occurrence of
LEADING-REGEXP by the string returned by REPLACEMENT in FILE. For example:
(emacs-substitute-sexps \"w3m.el\"
(\"defcustom w3m-command\"
(string-append w3m \"/bin/w3m\"))
(\"defvar w3m-image-viewer\"
(string-append imagemagick \"/bin/display\")))
This replaces the default values of the `w3m-command' and `w3m-image-viewer'
variables declared in `w3m.el' with the results of the `string-append' calls
above. Note that LEADING-REGEXP uses Emacs regexp syntax."
((emacs-substitute-sexps file (leading-regexp replacement) ...)
(emacs-batch-edit-file file
`(progn (progn (goto-char (point-min))
(re-search-forward ,leading-regexp)
(kill-sexp)
(insert " ")
(insert ,(format #f "~S" replacement)))
...
(basic-save-buffer))))))
(define-syntax emacs-substitute-variables
(syntax-rules ()
"Substitute the default value of VARIABLE by the string returned by
REPLACEMENT in FILE. For example:
(emacs-substitute-variables \"w3m.el\"
(\"w3m-command\" (string-append w3m \"/bin/w3m\"))
(\"w3m-image-viewer\" (string-append imagemagick \"/bin/display\")))
This replaces the default values of the `w3m-command' and `w3m-image-viewer'
variables declared in `w3m.el' with the results of the `string-append' calls
above."
((emacs-substitute-variables file (variable replacement) ...)
(emacs-substitute-sexps file
((string-append "(def[a-z]+[[:space:]\n]+" variable "\\>")
replacement)
...))))
;;; emacs-utils.scm ends here
|