build-system: Add 'texlive-build-system'.

* guix/build-system/texlive.scm: New file.
* guix/build/texlive-build-system.scm: New file.
* Makefile.am (MODULES): Add them.
* doc/guix.texi (Build Systems): Document it.
* gnu/packages/tex.scm (%texlive-tag, %texlive-revision): Remove variables.
(texlife-ref): Remove procedure.

2 files changed, 253 insertions, 0 deletions

diff --git a/guix/build-system/texlive.scm b/guix/build-system/texlive.scm
new file mode 100644
index 0000000000..d4085ea7e8
--- /dev/null
+++ b/guix/build-system/texlive.scm
@@ -0,0 +1,164 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2017 Ricardo Wurmus <rekado@elephly.net>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build-system texlive)
+  #:use-module (guix store)
+  #:use-module (guix utils)
+  #:use-module (guix packages)
+  #:use-module (guix derivations)
+  #:use-module (guix search-paths)
+  #:use-module (guix build-system)
+  #:use-module (guix build-system gnu)
+  #:use-module (guix svn-download)
+  #:use-module (ice-9 match)
+  #:export (%texlive-build-system-modules
+            texlive-build
+            texlive-build-system
+            texlive-ref
+            %texlive-tag
+            %texlive-revision))
+
+;; Commentary:
+;;
+;; Standard build procedure for Texlive packages.
+;;
+;; Code:
+
+;; These variables specify the SVN tag and the matching SVN revision.
+(define %texlive-tag "texlive-2017.0")
+(define %texlive-revision 44445)
+
+(define (texlive-ref component id)
+  "Return a <svn-reference> object for the package ID, which is part of the
+given Texlive COMPONENT."
+  (svn-reference
+   (url (string-append "svn://www.tug.org/texlive/tags/"
+                       %texlive-tag "/Master/texmf-dist/"
+                       "source/" component "/" id))
+   (revision %texlive-revision)))
+
+(define %texlive-build-system-modules
+  ;; Build-side modules imported by default.
+  `((guix build texlive-build-system)
+    ,@%gnu-build-system-modules))
+
+(define (default-texlive-bin)
+  "Return the default texlive-bin package."
+  ;; Lazily resolve the binding to avoid a circular dependency.
+  (let ((tex-mod (resolve-interface '(gnu packages tex))))
+    (module-ref tex-mod 'texlive-bin)))
+
+(define (default-texlive-latex-base)
+  "Return the default texlive-latex-base package."
+  ;; Lazily resolve the binding to avoid a circular dependency.
+  (let ((tex-mod (resolve-interface '(gnu packages tex))))
+    (module-ref tex-mod 'texlive-latex-base)))
+
+(define* (lower name
+                #:key
+                source inputs native-inputs outputs
+                system target
+                (texlive-latex-base (default-texlive-latex-base))
+                (texlive-bin (default-texlive-bin))
+                #:allow-other-keys
+                #:rest arguments)
+  "Return a bag for NAME."
+  (define private-keywords
+    '(#:source #:target #:inputs #:native-inputs
+      #:texlive-latex-base #:texlive-bin))
+
+  (bag
+    (name name)
+    (system system)
+    (host-inputs `(,@(if source
+                         `(("source" ,source))
+                         '())
+                   ,@inputs
+
+                   ;; Keep the standard inputs of 'gnu-build-system'.
+                   ,@(standard-packages)))
+    (build-inputs `(("texlive-bin" ,texlive-bin)
+                    ("texlive-latex-base" ,texlive-latex-base)
+                    ,@native-inputs))
+    (outputs outputs)
+    (build texlive-build)
+    (arguments (strip-keyword-arguments private-keywords arguments))))
+
+(define* (texlive-build store name inputs
+                        #:key
+                        (tests? #f)
+                        tex-directory
+                        (build-targets #f)
+                        (tex-format "luatex")
+                        (phases '(@ (guix build texlive-build-system)
+                                    %standard-phases))
+                        (outputs '("out"))
+                        (search-paths '())
+                        (system (%current-system))
+                        (guile #f)
+                        (substitutable? #t)
+                        (imported-modules %texlive-build-system-modules)
+                        (modules '((guix build texlive-build-system)
+                                   (guix build utils))))
+  "Build SOURCE with INPUTS."
+  (define builder
+    `(begin
+       (use-modules ,@modules)
+       (texlive-build #:name ,name
+                      #:source ,(match (assoc-ref inputs "source")
+                                       (((? derivation? source))
+                                        (derivation->output-path source))
+                                       ((source)
+                                        source)
+                                       (source
+                                        source))
+                      #:tex-directory ,tex-directory
+                      #:build-targets ,build-targets
+                      #:tex-format ,tex-format
+                      #:system ,system
+                      #:tests? ,tests?
+                      #:phases ,phases
+                      #:outputs %outputs
+                      #:search-paths ',(map search-path-specification->sexp
+                                            search-paths)
+                      #:inputs %build-inputs)))
+
+  (define guile-for-build
+    (match guile
+      ((? package?)
+       (package-derivation store guile system #:graft? #f))
+      (#f                               ; the default
+       (let* ((distro (resolve-interface '(gnu packages commencement)))
+              (guile  (module-ref distro 'guile-final)))
+         (package-derivation store guile system #:graft? #f)))))
+
+  (build-expression->derivation store name builder
+                                #:inputs inputs
+                                #:system system
+                                #:modules imported-modules
+                                #:outputs outputs
+                                #:guile-for-build guile-for-build
+                                #:substitutable? substitutable?))
+
+(define texlive-build-system
+  (build-system
+    (name 'texlive)
+    (description "The build system for TeX Live packages")
+    (lower lower)))
+
+;;; texlive.scm ends here
diff --git a/guix/build/texlive-build-system.scm b/guix/build/texlive-build-system.scm
new file mode 100644
index 0000000000..c1fd9fd9af
--- /dev/null
+++ b/guix/build/texlive-build-system.scm
@@ -0,0 +1,89 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2017 Ricardo Wurmus <rekado@elephly.net>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build texlive-build-system)
+  #:use-module ((guix build gnu-build-system) #:prefix gnu:)
+  #:use-module (guix build utils)
+  #:use-module (ice-9 match)
+  #:use-module (srfi srfi-1)
+  #:use-module (srfi srfi-26)
+  #:export (%standard-phases
+            texlive-build))
+
+;; Commentary:
+;;
+;; Builder-side code of the standard build procedure for TeX Live packages.
+;;
+;; Code:
+
+(define (compile-with-latex format file)
+  (zero? (system* format
+                  "-interaction=batchmode"
+                  "-output-directory=build"
+                  (string-append "&" format)
+                  file)))
+
+(define* (build #:key inputs build-targets tex-format #:allow-other-keys)
+  ;; Find additional tex and sty files
+  (setenv "TEXINPUTS"
+          (string-append
+           (getcwd) ":" (getcwd) "/build:"
+           (string-join
+            (append-map (match-lambda
+                          ((_ . dir)
+                           (find-files dir
+                                       (lambda (_ stat)
+                                         (eq? 'directory (stat:type stat)))
+                                       #:directories? #t
+                                       #:stat stat)))
+                        inputs)
+            ":")))
+  (setenv "TEXFORMATS"
+          (string-append (assoc-ref inputs "texlive-latex-base")
+                         "/share/texmf-dist/web2c/"))
+  (setenv "LUAINPUTS"
+          (string-append (assoc-ref inputs "texlive-latex-base")
+                         "/share/texmf-dist/tex/latex/base/"))
+  (mkdir "build")
+  (every (cut compile-with-latex tex-format <>)
+         (if build-targets build-targets
+             (find-files "." "\\.ins$"))))
+
+(define* (install #:key outputs tex-directory #:allow-other-keys)
+  (let* ((out (assoc-ref outputs "out"))
+         (target (string-append
+                  out "/share/texmf-dist/tex/" tex-directory)))
+    (mkdir-p target)
+    (for-each delete-file (find-files "." "\\.(log|aux)$"))
+    (for-each (cut install-file <> target)
+              (find-files "build" ".*"))
+    #t))
+
+(define %standard-phases
+  (modify-phases gnu:%standard-phases
+    (delete 'configure)
+    (replace 'build build)
+    (delete 'check)
+    (replace 'install install)))
+
+(define* (texlive-build #:key inputs (phases %standard-phases)
+                        #:allow-other-keys #:rest args)
+  "Build the given TeX Live package, applying all of PHASES in order."
+  (apply gnu:gnu-build #:inputs inputs #:phases phases args))
+
+;;; texlive-build-system.scm ends here